【Unity】ペンキをぶっかけた人型を作ってみた

/*****************************************************************************
*	$Id: $
*	深度チェック付きプロジェクションシェーダー
*****************************************************************************/
Shader "Custom/DepthProjector"
{
	Properties
	{
		_MainTex( "Source", 2D) = "white" {}
		_DepthTex( "DepthTexture", 2D) = "white" {}
	}
	SubShader
	{
		Cull Back
		Fog { Mode Off }
		Pass
		{
			Tags { "RenderType"="Opaque" "Queue"="Geometry+10"}
			Blend SrcAlpha OneMinusSrcAlpha
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "UnityLightingCommon.cginc"
			struct appdata
			{
				float4 vertex : POSITION;
				float4 normal : NORMAL;
			};
			struct v2f
			{
				float4 vertex : SV_POSITION;
				float4 uv : TEXCOORD0;
				float4 projector_vertex : TEXCOORD1; // u, v, depth
				fixed4 diff : COLOR0; // 拡散ライティングカラー
			};
			float4x4 unity_Projector;
			float4x4 _DepthVP;
			float3 _DepthDir;
			sampler2D _MainTex; // カラーテクスチャー
			sampler2D _DepthTex; // 深度テクスチャー
			// 頂点シェーダー
			v2f vert( appdata v)
			{
				v2f o;
				// メインカメラからの座標
				o.vertex =  UnityObjectToClipPos( v.vertex);
				o.uv = mul( unity_Projector, v.vertex);
				// プロジェクター視点の座標
				float3 posv = mul( UNITY_MATRIX_M, v.vertex);
				o.projector_vertex = mul( _DepthVP, float4( posv, 1));
				// プロジェクター視点の法線
				float3 normalv = mul( UNITY_MATRIX_M, v.normal);
				o.uv.z = dot( normalv, _DepthDir);
				//法線とライト方向間のドット積
				half3 worldNormal = UnityObjectToWorldNormal(v.normal);
				half nl = max( 0, dot( worldNormal, _WorldSpaceLightPos0.xyz));
				// ライトカラーの積
				o.diff = nl * _LightColor0;
				return o;
			}
			// フラグメントシェーダー
			fixed4 frag( v2f i) : SV_Target
			{
				// クリッピング
				if( abs( i.projector_vertex.x / i.projector_vertex.w) > 1)
				{
					discard; // 中止
				}
				if( abs( i.projector_vertex.y / i.projector_vertex.w) > 1)
				{
					discard; // 中止
				}
				// 法線チェック
				if( i.uv.z < 0.0)
				{
					discard; // 中止
				}
				float depth = i.projector_vertex.z;
				float4 depth_tex = tex2Dproj( _DepthTex, i.uv);
				// 差が大きいなら最前面ではないだろう
				if( abs( depth - depth_tex.r) >= 0.01)
				{
					discard; // 中止
				}
				fixed4 col = tex2Dproj( _MainTex, i.uv);
				col *= i.diff;
				return col;
			}
			ENDCG
		}
	}
}

				o.uv = mul( unity_Projector, v.vertex);

/*****************************************************************************
*	$Id: $
*	深度チェック付きプロジェクター
*****************************************************************************/
using System.Collections;
using System.Collections.Generic;
using UnityEngine;
public class DepthProjector : MonoBehaviour {
	// プロジェクター本体
	private Projector projector{ get; set; }
	// プロジェクターで描画するマテリアル
	private Material projectorMaterial{ get; set; }
	// プロジェクタに付いているカメラ
	private Camera depthCamera{ get; set; }
	//----------------------------------------------------------------------------
	void Start()
	{
		projector = GetComponent<Projector>();
		projectorMaterial = projector?.material;
		depthCamera = GetComponent<Camera>();
	}
	//----------------------------------------------------------------------------
	// 描画前に呼ばれる
	void OnPreRender()
	{
		// プロジェクターから見た射影行列をシェーダーに送る。
		var decalVMatrix = depthCamera.worldToCameraMatrix;
		var decalPMatrix = GL.GetGPUProjectionMatrix( depthCamera.projectionMatrix, false);
		var decalVP = decalPMatrix * decalVMatrix;
		projectorMaterial?.SetMatrix( "_DepthVP", decalVP);
		// ついでに視線ベクトルも送る。
		var decalDir = depthCamera.transform.TransformDirection( new Vector3( 0, 0, 1));
		projectorMaterial?.SetVector( "_DepthDir", decalDir);
	}
}